Transpondeur A320

Manette de train ou de Volets, volants, palonniers, manettes de gaz, throttle, etc...

Transpondeur A320

Messagede stive » Dim 11 Mar 2012 23:35

Pour pouvoir réaliser le script du transpondeur sur mon cockpit, je voudrai connaitre son mode d'utilisation. J'ai lu et relu Airbus - La grande visite d'Arnaud Chaibi, grand MERCI à lui pour son fichier , on y trouve bien la fonction des différents boutons et commutateurs mais pas comment les utiliser.
Exemple:
Pour afficher un code à 4 chiffres, il faut commencer par actionner la touche CLR puis les 4 chiffres mais dans quel ordre ? On commence par le chiffre des milliers ou celui des unités ? gratgrat
Si parmi vous, il y a des connaisseurs des systèmes de l'A320 ?
D'avance MERCI

A+
Stive
Découvrez nos vols en Live sur Twitch
L'histoire du simulateur sur JL A320
Avatar de l’utilisateur
stive
 
Messages: 616
Inscription: 14/06/09
Localisation: Oise (60)

Re: Transpondeur A320

Messagede nuno14 » Lun 12 Mar 2012 14:31

Bonjour,
Il faut le taper dans l'ordre des milliers, centaine, dixaine et unité.

Si ça peut t'interressé je peut te donné le scripte, car je l'ai déjà fait et adapter au FMGS de jeehell.

@+

Nuno
Image
Avatar de l’utilisateur
nuno14
 
Messages: 175
Inscription: 14/09/10
Localisation: Près de Lisieux, Normandie

Re: Transpondeur A320

Messagede tabar57 » Lun 12 Mar 2012 14:57

Salut,

Ca m'interesse aussi et peut être d'autres si tu peux le mettre à dispo ce serai sympa ?

Merci

Bernard
Mon blog de construction : http://tabar57.blog4ever.com
Hémicockpit de Beechcraft B200 ( de FlightOne ) P3DV4.5 et 2 PC en réseau W7 64 bits et W10, cartes OC et FDbus, vibreur et yoke rdf de BFFsimulation, météo réelle asp4
Avatar de l’utilisateur
tabar57
 
Messages: 3651
Inscription: 29/12/10
Localisation: Dans ma cabine en Lorraine

Re: Transpondeur A320

Messagede stive » Lun 12 Mar 2012 20:47

Bonsoir Nuno,

Si ça peut t'interressé je peut te donné le scripte, car je l'ai déjà fait et adapter au FMGS de jeehell.


SUPER rigolus

Très intéressant, je suis preneur puisque j'utilise aussi le FMGS de JeeHell merci affiche

Je t'envoie un MP

A+
Stive
Découvrez nos vols en Live sur Twitch
L'histoire du simulateur sur JL A320
Avatar de l’utilisateur
stive
 
Messages: 616
Inscription: 14/06/09
Localisation: Oise (60)

Re: Transpondeur A320

Messagede nuno14 » Lun 12 Mar 2012 23:20

Voici le script du transpondeur.

Sur la variable 1169, penser a changer ou supprimer la ligne ALIM_ON qui indique si l'avionique est alimenter ou non ( Stive j'ai oublier de te le préciser sur le message yeuxhaut )


Code: Tout sélectionner
Var 1130, name CONTROL_FMGS, Link FSUIPC_INOUT, Offset $78ED, Length 1     // CONTROLE FMGS JEEHELL

Var 1131, name fs_transp, Link FSUIPC_INOUT, Offset $0354, Length 2
{
  &temp_tr_code = FROMBCD &fs_transp
  CALL &calc_temp_dgs
}

Var 1132, name aff_tr_dg4, Link IOCARD_DISPLAY, Digit 12, Numbers 1     // unités transp

Var 1133, name aff_tr_dg3, Link IOCARD_DISPLAY, Digit 13, Numbers 1     // dizaines transp

Var 1134, name aff_tr_dg2, Link IOCARD_DISPLAY, Digit 14, Numbers 1     // centaines transp

Var 1135, name aff_tr_dg1, Link IOCARD_DISPLAY, Digit 15, Numbers 1     // milliers transp

Var 1136, name aff_tr_code, Link IOCARD_DISPLAY, Digit 12, Numbers 4     // code entier

Var 1137, name press_count, Value 0     // nombre d'appuis

Var 1138, name current_digit, Value 1     // numéro du chiffre à afficher

Var 1139, name val_dg     // valeur chiffre courant

Var 1140, name temp_tr_dg1, Value 0     // valeur chiffre milliers

Var 1141, name temp_tr_dg2, Value 0     // valeur chiffre centaines

Var 1142, name temp_tr_dg3, Value 0     // valeur chiffre dizaines

Var 1143, name temp_tr_dg4, Value 0     // valeur chiffre unités

Var 1144, name temp_tr_code     // code temporaire pendans saisie

Var 1145, name mem_tr_code     // code précédent

Var 1146, name new_tr_code, Value 1     // à 0 pendant saisie, à 1 si nouveau code

Var 1147, name tr_push_0, Link IOCARD_SW, Input 45     // Push chiffre 0
{
  IF &tr_push_0 = 1
  {
    IF &press_count = 0
    {
      CALL &init_tempo
    }
    &val_dg = 0         // chiffre courant = 0
    CALL &place_dg, &val_dg     // met le chiffre à sa place en temporaire
    CALL &calc_temp_code     // calcul le nouveau code
    CALL &use_code     // vérifie si code entier
  }
}

Var 1148, name tr_push_1, Link IOCARD_SW, Input 46     // Push chiffre 1
{
  IF &tr_push_1 = 1
  {
    IF &press_count = 0
    {
      CALL &init_tempo
    }
    &val_dg = 1         // chiffre courant = 1
    CALL &place_dg, &val_dg     // met le chiffre à sa place en temporaire
    CALL &calc_temp_code
    CALL &use_code
  }
}

Var 1149, name tr_push_2, Link IOCARD_SW, Input 47     // Push chiffre 2
{
  IF &tr_push_2 = 1
  {
    IF &press_count = 0
    {
      CALL &init_tempo
    }
    &val_dg = 2         // chiffre courant = 2
    CALL &place_dg, &val_dg     // met le chiffre à sa place en temporaire
    CALL &calc_temp_code
    CALL &use_code
  }
}

Var 1150, name tr_push_3, Link IOCARD_SW, Input 48     // Push chiffre 3
{
  IF &tr_push_3 = 1
  {
    IF &press_count = 0
    {
      CALL &init_tempo
    }
    &val_dg = 3         // chiffre courant = 3
    CALL &place_dg, &val_dg     // met le chiffre à sa place en temporaire
    CALL &calc_temp_code
    CALL &use_code
  }
}

Var 1151, name tr_push_4, Link IOCARD_SW, Input 49     // Push chiffre 4
{
  IF &tr_push_4 = 1
  {
    IF &press_count = 0
    {
      CALL &init_tempo
    }
    &val_dg = 4         // chiffre courant = 4
    CALL &place_dg, &val_dg     // met le chiffre à sa place en temporaire
    CALL &calc_temp_code
    CALL &use_code
  }
}

Var 1152, name tr_push_5, Link IOCARD_SW, Input 50     // Push chiffre 5
{
  IF &tr_push_5 = 1
  {
    IF &press_count = 0
    {
      CALL &init_tempo
    }
    &val_dg = 5         // chiffre courant = 5
    CALL &place_dg, &val_dg     // met le chiffre à sa place en temporaire
    CALL &calc_temp_code
    CALL &use_code
  }
}

Var 1153, name tr_push_6, Link IOCARD_SW, Input 51     // Push chiffre 6
{
  IF &tr_push_6 = 1
  {
    IF &press_count = 0
    {
      CALL &init_tempo
    }
    &val_dg = 6         // chiffre courant = 6
    CALL &place_dg, &val_dg     // met le chiffre à sa place en temporaire
    CALL &calc_temp_code
    CALL &use_code
  }
}

Var 1154, name tr_push_7, Link IOCARD_SW, Input 52     // Push chiffre 7
{
  IF &tr_push_7 = 1
  {
    IF &press_count = 0
    {
      CALL &init_tempo
    }
    &val_dg = 7         // chiffre courant = 7
    CALL &place_dg, &val_dg     // met le chiffre à sa place en temporaire
    CALL &calc_temp_code
    CALL &use_code
  }
}

Var 1155, name CLR, Link IOCARD_SW, Input 53     // Push CLR
{
  IF &CLR = 1
  {
    &fs_transp = TOBCD 7000     // met le code 7000
    &temp_tr_dg1 = 7         // met les millers à 7 
    &temp_tr_dg2 = 0   
    &temp_tr_dg3 = 0   
    &temp_tr_dg4 = 0   
    CALL &affich_transp     // et l'affiche
  }
}

Var 1156, name sw_tr_off, Link IOCARD_SW, Input 38     // Inter Transp Off
{
  IF &sw_tr_off = 1
  {
    &tr_mode = 1   
    CALL &affich_transp
  }
}

Var 1157, name sw_tr_sby, Link IOCARD_SW, Input 39     // Transpondeur mode standby
{
  IF &sw_tr_sby = 1
  {
    &tr_mode = 1   
    &aff_tr_dg1 = &temp_tr_dg1   
    &aff_tr_dg2 = &temp_tr_dg2   
    &aff_tr_dg3 = &temp_tr_dg3   
    &aff_tr_dg4 = &temp_tr_dg4   
    CALL &affich_transp
  }
}

Var 1158, name sw_tr_chrly, Link IOCARD_SW, Input 40     // Transpondeur mode Charly
{
  IF &sw_tr_chrly = 1
  {
    &tr_mode = 0   
  }
}

Var 1159, name sw_tr_ident, Link IOCARD_SW, Input 17     // push ident transpondeur pour ivao
{
  IF &sw_tr_ident = 1
  {
    &tr_ident = 1   
  }
}

Var 1160, name tr_ident, Link FSUIPC_INOUT, Offset $7B93, Length 1     // ident ivao

Var 1161, name tr_mode, Link FSUIPC_INOUT, Offset $7B91, Length 2, Value 0     // mode transpondeur ivao

Var 1162, name tempo, Link SUBRUTINE     // temporisation saisie
{
  IF &tempo >= 400     // si temps terminé
  {
    IF &press_count < 4     // si code partiel saisi
    {
      &temp_tr_code = &mem_tr_code         // on remet l'ancien code 
      &fs_transp = TOBCD &temp_tr_code     // on le repasse à FS
      CALL &calc_temp_dgs     // et on calcule les chiffres
    }
    CALL &affich_transp     // on affiche les chiffres
    &press_count = 0         // et on réinitialise
    &new_tr_code = 1   
    &current_digit = 1   
  }
}

Var 1163, name init_tempo, Link SUBRUTINE     // initialisation tempo
{
  &tempo = 0   
  &tempo = TIMER 400 ,4 ,5
  &mem_tr_code = FROMBCD &fs_transp     // mémorisation ancien code
}

Var 1164, name place_dg, Link SUBRUTINE     // place les chiffres
{
  IF &press_count > 0     // si pas premier appui
  {
    &new_tr_code = 0         // pas un nouveau code
  }
  &press_count = &press_count + 1
  IF &current_digit = 1     // saisie du chiffre des milliers
  {
    &temp_tr_dg1 = &place_dg   
  }
  IF &current_digit = 2     // saisie du chiffre des centaines
  {
    &temp_tr_dg2 = &place_dg   
  }
  IF &current_digit = 3     // saisie du chiffre des dizaines
  {
    &temp_tr_dg3 = &place_dg   
  }
  IF &current_digit = 4     // saisie du chiffre des unités
  {
    &temp_tr_dg4 = &place_dg   
  }
  &current_digit = &current_digit + 1     // incrémente la position
  IF &current_digit = 5     // revient au premier chiffre après le 4e
  {
    &current_digit = 1   
  }
}

Var 1165, name calc_temp_code, Link SUBRUTINE     // calcule, envoie à FS et affiche la valeu
{
  L0 = &temp_tr_dg1 * 1000
  L1 = &temp_tr_dg2 * 100
  L2 = L0 + L1
  L1 = &temp_tr_dg3 * 10
  L2 = L2 + L1
  &temp_tr_code = L2 + &temp_tr_dg4
  &fs_transp = TOBCD &temp_tr_code
  CALL &affich_transp
}

Var 1166, name use_code, Link SUBRUTINE     // décision gader ou rejeter
{
  IF &press_count = 4     // code entier saisi
  {
    CALL &fin     // on garde le nouveau code
  }
  ELSE
  {
    CALL &tempo     // on agit selon timer
  }
}

Var 1167, name fin, Link SUBRUTINE     // termine le traitement
{
  &new_tr_code = 1         // réinitialise pour nouevau code
  &current_digit = 1         // réinitialise chiffre à 1
  &fs_transp = TOBCD &temp_tr_code     // envoi code à FS
}

Var 1168, name calc_temp_dgs, Link SUBRUTINE     // calcule les chiffres d'après le code si
{
  &temp_tr_dg1 = DIV &temp_tr_code ,1000
  &temp_tr_dg4 = MOD &temp_tr_code ,10
  L0 = &temp_tr_dg1 * 1000
  L1 = &temp_tr_code - L0
  &temp_tr_dg2 = DIV L1 ,100
  L2 = &temp_tr_dg2 * 100
  L0 = L1 - L2
  &temp_tr_dg3 = DIV L0 ,10
}

Var 1169, name affich_transp, Link SUBRUTINE     // affiche les 7 segments
{
  C0 = &sw_tr_off = 1
  C1 = &ALIM_ON = 0     // pas de courant
  C2 = C0 OR C1
  IF C2 OR C1     // pas de courant ou transpondeur coupé
  {
    &affich_transp = 0   
    &aff_tr_dg1 = 10         // on éteint les chiffres
    &aff_tr_dg2 = 10   
    &aff_tr_dg3 = 10   
    &aff_tr_dg4 = 10   
  }
  ELSE
  {
    &affich_transp = 0   
    &aff_tr_dg1 = &temp_tr_dg1   
    &aff_tr_dg2 = &temp_tr_dg2   
    &aff_tr_dg3 = &temp_tr_dg3   
    &aff_tr_dg4 = &temp_tr_dg4   
    &aff_tr_code = &temp_tr_code   
  }
}

Var 1170, name TCAS_ALL, Link IOCARD_SW, Input 14     // BOUTON TCAS ALL
{
  IF &TCAS_ALL = 1
  {
    &CONTROL_FMGS = 32   
    &POS_TCAS_THRT = 0   
  }
  ELSE
  {
    &CONTROL_FMGS = 0   
    &POS_TCAS_THRT = 1   
  }
}

Var 1171, name TCAS_ABV, Link IOCARD_SW, Input 15     // BOUTON TCAS ABV
{
  IF &TCAS_ABV = 1
  {
    &CONTROL_FMGS = 35   
    &POS_TCAS_THRT = 0   
  }
  ELSE
  {
    &CONTROL_FMGS = 0   
    &POS_TCAS_THRT = 1   
  }
}

Var 1172, name TCAS_BLW, Link IOCARD_SW, Input 16     // BOUTON TCAS BLW
{
  IF &TCAS_BLW = 1
  {
    &CONTROL_FMGS = 34   
    &POS_TCAS_THRT = 0   
  }
  ELSE
  {
    &CONTROL_FMGS = 0   
    &POS_TCAS_THRT = 1   
  }
}

Var 1173, name TCAS_TA, Link IOCARD_SW, Input 36     // BOUTON TCAS TA
{
  IF &TCAS_TA = 1
  {
    &CONTROL_FMGS = 38   
    &POS_TCAS_STBY = 0   
  }
  ELSE
  {
    &CONTROL_FMGS = 0   
    &POS_TCAS_STBY = 1   
  }
}

Var 1174, name TCAS_TARA, Link IOCARD_SW, Input 14     // BOUTON TCAS TA/RA
{
  IF &TCAS_TARA = 1
  {
    &CONTROL_FMGS = 37   
    &POS_TCAS_STBY = 0   
  }
  ELSE
  {
    &CONTROL_FMGS = 0   
    &POS_TCAS_STBY = 1   
  }
}

Var 1175, name POS_TCAS_THRT     // POSITION TCAS THRT
{
  IF &POS_TCAS_THRT = 1
  {
    &CONTROL_FMGS = 33   
  }
  ELSE
  {
    &CONTROL_FMGS = 0   
  }
}

Var 1176, name POS_TCAS_STBY     // POSITION TCAS STANDBY
{
  IF &POS_TCAS_STBY = 1
  {
    &CONTROL_FMGS = 36   
  }
  ELSE
  {
    &CONTROL_FMGS = 0   
  }
}
Avatar de l’utilisateur
nuno14
 
Messages: 175
Inscription: 14/09/10
Localisation: Près de Lisieux, Normandie

Re: Transpondeur A320

Messagede stive » Mar 13 Mar 2012 23:05

MERCI Nuno,

SUPER boulot applaublanc applaublanc

A+

Stive
Découvrez nos vols en Live sur Twitch
L'histoire du simulateur sur JL A320
Avatar de l’utilisateur
stive
 
Messages: 616
Inscription: 14/06/09
Localisation: Oise (60)

Re: Transpondeur A320

Messagede nuno14 » Mar 13 Mar 2012 23:15

Ce n'est pas moi qu'il faut remercier nondoightblanc , c'est un autre membre de ce forum qui m'a donner ce script, il sagit de KELT760. Je n'est rajouter que les variables pour le FMGS de jeehell.

Bravo et merci affiche à lui applaublanc applaublanc applaublanc .
Image
Avatar de l’utilisateur
nuno14
 
Messages: 175
Inscription: 14/09/10
Localisation: Près de Lisieux, Normandie

Re: Transpondeur A320

Messagede tabar57 » Mar 13 Mar 2012 23:38

Bonjour Nuno,

Merci pour ce code je vais décortiquer tout çà pour l'adapter à mon petit B200.
Chapeau pour l'esprit de partage

Bonne soirée

Bernard
Mon blog de construction : http://tabar57.blog4ever.com
Hémicockpit de Beechcraft B200 ( de FlightOne ) P3DV4.5 et 2 PC en réseau W7 64 bits et W10, cartes OC et FDbus, vibreur et yoke rdf de BFFsimulation, météo réelle asp4
Avatar de l’utilisateur
tabar57
 
Messages: 3651
Inscription: 29/12/10
Localisation: Dans ma cabine en Lorraine

Re: Transpondeur A320

Messagede nuno14 » Mer 14 Mar 2012 23:16

tabar57 a écrit:Bonjour Nuno,

Merci pour ce code je vais décortiquer tout çà pour l'adapter à mon petit B200.
Chapeau pour l'esprit de partage

Bonne soiré

Bernard



gratgrat gratgrat peurefrayé
C'est pas l'esprit du forum le partage.
Image
Avatar de l’utilisateur
nuno14
 
Messages: 175
Inscription: 14/09/10
Localisation: Près de Lisieux, Normandie

Re: Transpondeur A320

Messagede Boutondair » Mer 14 Mar 2012 23:20

Bien sur que SI applaublanc

David cligneoeil
Image Image
Petit je rêvais que je volerais, maintenant grâce au virtuel je vole !!!!!
Avatar de l’utilisateur
Boutondair
Administrateur du site
 
Messages: 4174
Inscription: 20/04/09
Localisation: Ballans (17) proche de Cognac

Suivante

Retourner vers Commandes de vols





Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 2 invités

cron